
 1000  *SAVE S.LOCATOR
 1010  *--------------------------------
 1020         .OR $292     HIGH END OF INPUT BUFFER
 1030  *      .TF LOCATOR
 1040  *--------------------------------
 1050  ZERO       .EQ 0
 1060   
 1070  MON.PRNTAX .EQ $F941
 1080  MON.COUT   .EQ $FDED
 1090  MON.CROUT  .EQ $FD8E
 1100  *--------------------------------
 1110  START  LDX #0
 1120   
 1130  LOOP   JSR MON.CROUT     NEW LINE
 1140         TXA
 1150         LSR               MAKE (X)
 1160         ASL               INTO
 1170         ASL               TITLE
 1180         ASL               INDEX
 1190         TAY
 1200  .1     LDA TITLES,Y      SHOW TITLE
 1210         JSR MON.COUT
 1220         INY
 1230         CMP #':+$80       ":" ?
 1240         BNE .1
 1250   
 1260         LDY #1            FILL WITH " $"
 1270         JSR PRINT.ADDRESS
 1280         LDY #4            FILL WITH " TO $"
 1290         JSR PRINT.ADDRESS
 1300         CPX #7            DONE YET?
 1310         BCC LOOP          NO, GO ON
 1320         JMP $3D0          YES, EXIT TO DOS
 1330  *--------------------------------
 1340  PRINT.ADDRESS
 1350  .1     LDA FILLER,Y      Y TELLS HOW
 1360         JSR MON.COUT      MUCH FILLER
 1370         DEY               TO PRINT
 1380         BPL .1
 1390   
 1400         TXA
 1410         PHA               SAVE X
 1420         LDY TABLE,X       GET POINTER
 1430         LDA ZERO+1,Y      GET HIGH BYTE
 1440         LDX ZERO,Y        GET LOW BYTE
 1450         JSR MON.PRNTAX    DISPLAY ADDRESS
 1460         PLA
 1470         TAX               RESTORE X
 1480         INX               AND GET READY
 1490         RTS               FOR NEXT PASS
 1500  *--------------------------------
 1510  TITLES
 1520         .AS -/PROGRAM:/
 1530         .AS -/ SIMPLE:/
 1540         .AS -/ ARRAYS:/
 1550         .AS -/STRINGS:/
 1560  *--------------------------------
 1570  TABLE  .DA #$67,#$AF     START OF PROGRAM, END OF PROGRAM
 1580         .DA #$69,#$6B     START OF VARIABLES, START OF ARRAYS
 1590         .DA #$6B,#$6D     START OF ARRAYS, END OF NUMERICS
 1600         .DA #$6F,#$73     START OF STRINGS, HIMEM
 1610  *--------------------------------
 1620  FILLER .AS -/$ OT /

